plugins {
    id 'net.neoforged.gradle.userdev' version '7.0.+'
    id 'org.spongepowered.mixin' version '0.7.+'
    id 'maven-publish'
}

var mod_version = project.mod_version

archivesBaseName = project.archives_base_name
version = mod_version
group = maven_group

java.toolchain.languageVersion = JavaLanguageVersion.of(java_version as int)

sourceSets.main.resources.srcDirs += 'src/generated/resources'
mixin.add sourceSets.main, "webdisplays.refmap.json"

repositories {
    maven {
        name = "cursemaven"
        url = "https://www.cursemaven.com"
    }
    maven { 
        name = 'mcef-releases'
        url = 'https://mcef-download.cinemamod.com/repositories/releases/' 
    }
    maven {
        name = 'neoforged'
        url = 'https://maven.neoforged.net/releases'
    }
}

dependencies {
    implementation 'net.neoforged:neoforge:21.1.203'
    annotationProcessor 'org.spongepowered:mixin:0.8.5:processor'

    // useful for debugging performance problems
    implementation "curse.maven:spark-361579:4381167"
    // here because we need to manually open the VR keyboard
    compileOnly "curse.maven:vivecraft-667903:4794431"

    implementation("com.cinemamod:mcef-neoforge:2.1.6-1.21.1") {
        transitive = false
    }
}

jar {
    manifest {
        attributes([
                "Specification-Title": "WebDisplays",
                "Specification-Vendor": "CinemaMod Group",
                "Specification-Version": "1",
                "Implementation-Title": project.name,
                "Implementation-Version": project.version,
                "Implementation-Vendor": "CinemaMod Group",
                "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                "MixinConfigs": "webdisplays.mixins.json"
        ])
    }
}